Affichage des icônes des fichiers sur le bureau

gmaa · 21 Avril 2011

Bonjour,

Je suis confronté à une bizarrerie soudaine. Les icônes des fichiers .gif et .jpg ne s'affichent plus en miniatures image. Je n'ai plus que l'icône générique.
"Lire les informations" affiche correctement l'aperçu en grand correctement mais l'icône s'affiche en générique. En sélectionnant l'icône, on ne peut la "Couper".
J'ai tous les droits sur les fichiers.
Un aller-retour sous PhotoShop "rétablit" une icône-image...

Quel paramètre gère cet affichage?
Peut-on rétablir cet icône-image sans traiter le fichier par PhotoShop ou équivalent?

Je suis sous Mac OS 10.6.7

Note : L'image des icônes "correctes" vient d'un autre Mac de mon réseau.

tombom · 21 Avril 2011

bonjour,
un petit tour dans finder / barre de menu : presentation / afficher les options de presentations.

La case "utiliser un aperçu comme icône est bien cochée " ?

gmaa · 21 Avril 2011

Bonsoir,

J'ai bien sûr regardé de ce côté...
Mais cela ne suffit pas.

Dans l'image ci-jointe "Chat.gif" devrait s'afficher comme "Chat2.gif".

Bon, je sais contourner mais je voudrais savoir!

(Un Reset Finder ou un redémarrage ne change rien, la réparation des autorisations du disque non plus.)

tombom · 21 Avril 2011

peut etre un nettoyage des caches ? (Onyx ou autre...)

gmaa · 21 Avril 2011

Il fallait essayer...

Ben non!

En fait l'icône a été "coupée". Même comportement.

Donc il n'y a pas de solution.
La seule : Ouvrir le fichier sous un "Éditeur" ; Tout sélectionner ; Copier ; Coller.

Merci pour la suggestion.

Je vais clore la discussion.

gmaa · 22 Avril 2011

gmaa a dit:
Il fallait essayer...

Ben non!

En fait l'icône a été "coupée". Même comportement.

Donc il n'y a pas de solution.
La seule : Ouvrir le fichier sous Aperçu ; Tout sélectionner ; Copier ; Lire les infos ; Sélectionner l'icône ;Coller.

Merci pour la suggestion.

Je vais clore la discussion.

La discussion continue!

Comment forcer Finder à regénérer les icônes des fichiers images (png, gif, jpg, ...) pour les afficher en images?
Tous les paramètres de présentation du Finder sont cochés.
Virer les préférences de Finder (.plist) ne change rien.

Ma solution est viable pour quelques fichiers, pas pour tous...
Le processus est très itératif.
Ouvrir le fichier sous Aperçu ; Tout sélectionner ; Copier ; Re-sélectionner le fichier ; Lire les infos ; Sélectionner l'icône ;Coller
Je verrai bien un Script AppleScript (ou Automator?) mais ...

Si quelqu'un a une solution...

ceslinstinct · 23 Avril 2011

gmaa a dit:
La discussion continue!

Comment forcer Finder à regénérer les icônes des fichiers images (png, gif, jpg, ...) pour les afficher en images?
Tous les paramètres de présentation du Finder sont cochés.
Virer les préférences de Finder (.plist) ne change rien.

Ma solution est viable pour quelques fichiers, pas pour tous...
Le processus est très itératif.
Ouvrir le fichier sous Aperçu ; Tout sélectionner ; Copier ; Re-sélectionner le fichier ; Lire les infos ; Sélectionner l'icône ;Coller
Je verrai bien un Script AppleScript (ou Automator?) mais ...

Si quelqu'un a une solution...

Bonjour

Pour avoir les icônes d'affichées sur certains fichiers images, j'utilise un code AS qui fait le même travail que toi en passant par commande (défunt pomme) I sans a avoir l'affichage des fenêtres.

Application que j'utilise pour mes dossiers d'images sans problème pour le moment avec Léopard 10.5.8

Si tu veut tester sur une copie d'un de tes dossiers d'images, le code ci-dessous.

Bloc de code:

-- \\\ EN SÉLECTION MANUELLE DU DOSSIER D'IMAGES /// --

on run -- En sélection manuelle du dossier
	set ceDossier to choose folder -- Choix du dossier
	open {result} -- On lance le dossier sélectionné 
end run

-- \\\ EN SÉLECTION PAR GLISSER-DÉPOSER DU DOSSIER D'IMAGES /// --

on open ceDossier -- Sélection par Gliser-Déposer
	tell application "Finder" to set cheminsFichiers to every file of folder (ceDossier as alias) -- Contenu des fichiers du dossier sélectionné
	
	repeat with cheminLue in cheminsFichiers
		
		try -- Pour la gestion des fichiers causant des problèmes
			set cheminLue to (quoted form of POSIX path of (cheminLue as string))
			set fichierTemporaire to quoted form of (do shell script "mktemp -t sipsFile")
			
			do shell script "touch -r " & cheminLue & space & fichierTemporaire
			do shell script "sips -i " & cheminLue
			do shell script "touch -r " & fichierTemporaire & space & cheminLue
			do shell script "rm " & fichierTemporaire
		end try -- Passe si un problème avec le fichier lue
		
	end repeat
	
	display dialog "Terminé" buttons {"Ok"} default button "Ok" with title "ICÔNES" giving up after 5
	
end open

-- \\\ FIN DU CODE /// --

Sans garantie que ça fonctionne chez toi, mais qui tente rien est sur de ne pas trouver la réponse recherché.

Le choix se fait que sur des dossiers avec ce code, a toi de modifier suivant tes goûts.

C'est de l'AppleScript avec des commandes du Terminal alors question rapidité c'est quand même plus rapide que toi, mais c'est long pour plusiers milliers d'images.

Bon test (si tu as le courage).

@+

gmaa · 23 Avril 2011

Bonjour,

J'avais raison de poser la question!

Merci l'ami, ça marche à merveille!

J'ai rien modifié!

Cela pourra servir à d'autres...

ceslinstinct · 23 Avril 2011

gmaa a dit:
Bonjour,

J'avais raison de poser la question!

Merci l'ami, ça marche à merveille!

J'ai rien modifié!

Cela pourra servir à d'autres...

Bonjour

Plus qu'a demander à un modérateur d'inscrire Résolu si ce code te satisfait.

@+

C'est fait…

ceslinstinct · 24 Avril 2011

Bonjour

Un oublie de ma part sur l'utilisation du code. :mad:

Tu ouvre le dossier d'images sur le bureau et après tu lance le code.

Il te reste plus qu'a regarder le travail que fait le code, ça remplace la barre de défilement pour te faire patienter.

@+

gmaa · 24 Avril 2011

Bonsoir,

Ce code marche très bien.

J'en ai fait plusieurs applis pour les utiliser en //.
Avec un "glisser-déposer" des dossiers "images" sur les applis cela va plus vite…

Mais...

Un léger regret après une utilisation intensive (des dizaines de milliers d'icônes)

,
la récursivité...

Ce serait de toute façon à utiliser avec prudence. Mais cela rendrait service en n'ayant pas à scruter chaque brin des arborescences.

J'ai vu aussi que la récursivité totale en AS n'est pas "évidente". :siffle:

Enfin si un génie inspiré...

ceslinstinct · 25 Avril 2011

gmaa a dit:
Bonsoir,

Ce code marche très bien.
J'en ai fait plusieurs applis pour les utiliser en //.
Avec un "glisser-déposer" des dossiers "images" sur les applis cela va plus vite

Mais...

Un léger regret après une utilisation intensive (des dizaines de milliers d'icônes),
la récursivité...

Ce serait de toute façon à utiliser avec prudence. Mais cela rendrait service en n'ayant pas à scruter chaque brin des arborescences.

J'ai vu aussi que la récursivité totale en AS n'est pas "évidente". :siffle:

Enfin si un génie inspiré...

Bonjour

Remplace la ligne:

Bloc de code:

tell application "Finder" to set cheminsFichiers to every file of folder (ceDossier as alias)

par

Bloc de code:

tell application "Finder" to set cheminsFichiers to every file of entire contents of folder (ceDossier as alias)

Ca permet de gérer tous les fichiers contenu dans le dossier sélectionné ainsi que les sous-dossiers.

@+

gmaa · 25 Avril 2011

Bonjour,

C'est simple quand on sait!...

Merci encore!

J'ai baptisé l'application "Géricô".

Joyeuses Pâques (puisque c'est l'époque).

ceslinstinct · 25 Avril 2011

gmaa a dit:
Bonjour,

C'est simple quand on sait!...

Merci encore!

J'ai baptisé l'application "Géricô".

Joyeuses Pâques (puisque c'est l'époque).

Bonjour

Lors de l'utilisation, si tu as ceci: Délai dépassé pour un AppleEvent car un temps trop long d'utilisation.

Avec timeout 0 secondes désactive le délai d'attente, il semble.

Je l'utilise souvent sans problème.

Donc:

Bloc de code:

with timeout of 0 seconds
repeat with cheminLue in cheminsFichiers

-- le code

end repeat
end timeout

Le code donné, était pour quelques fichiers et non des millions, donc le temps n'est pas le même

@+

gmaa · 25 Avril 2011

Effectivement j'ai eu cette erreur pour de gros dossiers.
J'ai divisé pour régner!

Cela va finir par devenir une application "tout terrain".

J'ai mis les deux possibilités dans le fichier (mono ou Multi dossiers),
il ne reste plus qu'à y insérer un choix à la volée.

Voici "ma" copie.

-- \\\ EN SÉLECTION MANUELLE DU DOSSIER D'IMAGES /// --

on run -- En sélection manuelle du dossier
set ceDossier to choose folder -- Choix du dossier
open {result} -- On lance le dossier sélectionné
end run

-- \\\ EN SÉLECTION PAR GLISSER-DÉPOSER DU DOSSIER D'IMAGES /// --

on open ceDossier -- Sélection par Gliser-Déposer
-- \\\ Deux utilisations possibles /// --

-- 1 - Contenu des fichiers du dossier sélectionné (1 seul niveau - pas les sous-dossiers)
--tell application "Finder" to set cheminsFichiers to every file of folder (ceDossier as alias)

-- ou

-- 2 -Contenu des fichiers du dossier sélectionné et de tous ses sous-dossiers.
tell application "Finder" to set cheminsFichiers to every file of entire contents of folder

with timeout of 0 seconds
-- Aller au bout coûte que coûte.

repeat with cheminLue in cheminsFichiers

try -- Pour la gestion des fichiers causant des problèmes
set cheminLue to (quoted form of POSIX path of (cheminLue as string))
set fichierTemporaire to quoted form of (do shell script "mktemp -t sipsFile")

do shell script "touch -r " & cheminLue & space & fichierTemporaire
do shell script "sips -i " & cheminLue
do shell script "touch -r " & fichierTemporaire & space & cheminLue
do shell script "rm " & fichierTemporaire
end try -- Passe si un problème avec le fichier lue

end repeat

end timeout

display dialog "Géricô - Terminé" buttons {"Ok"} default button "Ok" with title "ICÔNES" giving up after 5

end open

-- \\\ FIN DU CODE /// --

ceslinstinct · 25 Avril 2011

gmaa a dit:
Effectivement j'ai eu cette erreur pour de gros dossiers.
J'ai divisé pour régner!

Cela va finir par devenir une application "tout terrain".

J'ai mis les deux possibilités dans le fichier (mono ou Multi dossiers),
il ne reste plus qu'à y insérer un choix à la volée.

Bonjour

Teste ce code (ne fonctionne que par sélection)

Il permet (normalement) de gérer un seul fichier, les fichiers d'un dossier où les fichiers d'un dossier et de ses sous-dossiers suivant ton choix.

Bloc de code:

-- CRÉER ICÔNES LIRE LES INFORMATIONS

-- © Légal Jean Louis (24 Janvier 2011)
-- Version 0.0.1 &#945; Testé avec Leopard 10.5.8
-- Ce code est distribué sous la licence GNU GENERAL PUBLIC 

-- ######################## --
-- \\\ INITIALISATION DES VARIABLES /// --
-- ######################## --

property memChoix : "Un fichier image" -- Utilisé pour la première utilisation du code (garde en mémoire la dernière sélection)
property mem : 0 -- Mémoire du bouton sélectionné (si c'est pas Quitter)

-- ############ --
-- \\\ VOTRE CHOIX /// --
-- ############ --

on run
	set liste to {"Un fichier image", "Un dossier d'images", "Toutes les images, dossier et sous-dossiers"} -- Noms des lignes dans la boite de dialogue (seul seul choix)
	-- Votre sélection
	set choix to (choose from list liste with prompt "" default items memChoix OK button name "OK" cancel button name "Quitter" with title "VOTRE SÉLECTION") as string
	if choix contains "false" then return -- Bouton Quitter
	
	tell me to activate -- Être sur que la fenêtre de dialogue soit en premier plan
	if choix is "Un fichier image" then -- Qu'un fichier seulement à gérer
		set mem to 1 -- Qu'un fichier à sélectionner
		open {choose file} -- Votre choix du fichier
	else if choix is "Un dossier d'images" then -- Connu des fichiers d'un dossier à gérer
		set mem to 2 -- Qu'un dossier à sélectionner
		open {choose folder} -- Votre choix du dossier
	else if choix is "Toutes les images, dossier et sous-dossiers" then -- Contenu des fichiers du dossier et de ses sous-dossiers
		set mem to 3 -- Qu'un dossier à sélectionner, mais ces sous-dossiers seront pris en compte
		open {choose folder} -- Votre choix du dossier maître
	end if
	
	set memChoix to choix -- Garde le contenu de la dernière sélection utilisée, pour la prochaine ouverture de cette application
	
end run

-- ####################### --
-- \\\ CRÉATION DE OÙ DES APERÇUS /// --
-- ####################### --

on open chemin
	
	if mem is 1 then -- Si un fichier seul sélectionné
		
		-- #################### --
		-- \\\ CHOIX D'UN SEUL FICHIER /// --
		-- #################### --
		
		try -- Création du fichiers icône
			set fichierTemporaire to do shell script "mktemp -t sipsFile"
			do shell script "touch -r " & (quoted form of POSIX path of chemin) & space & (quoted form of fichierTemporaire)
			do shell script "sips -i " & quoted form of POSIX path of chemin
			do shell script "touch -r " & (quoted form of fichierTemporaire) & space & (quoted form of POSIX path of chemin)
			do shell script "rm " & quoted form of fichierTemporaire
		end try
		tell me to activate -- Être sur que la fenêtre de dialogue soit en premier plan
		display dialog "Géricô - Terminé" buttons {"Ok"} default button "Ok" with title "ICÔNES" giving up after 5 -- Alerte de fin de travail
		return -- Quitte le code
		
		-- ####################### --
		-- \\\ CHOIX DE PLUSIEURS FICHIERS /// --
		-- ####################### --
		
	else if mem is 2 then -- Si que le contenu des fichiers du dossier sélectionné
		tell application "Finder" to set cheminsFichiers to every file of folder (chemin as string)
	else if mem is 3 then -- Contenu des fichiers du dossier sélectionné et les fichiers de ses sous-dossier
		tell application "Finder" to set cheminsFichiers to every file of entire contents of folder (chemin as string)
	end if
	
	with timeout of 0 seconds
		-- Création des icônes des fichiers
		repeat with i from 1 to (count item of cheminsFichiers)
			try
				set cheminLue to item i of cheminsFichiers as alias
				set fichierTemporaire to (do shell script "mktemp -t sipsFile")
				do shell script "touch -r " & (quoted form of POSIX path of cheminLue) & space & (quoted form of fichierTemporaire)
				do shell script "sips -i " & quoted form of POSIX path of cheminLue
				do shell script "touch -r " & (quoted form of fichierTemporaire) & space & (quoted form of POSIX path of cheminLue)
				do shell script "rm " & quoted form of fichierTemporaire
			end try
			
		end repeat
	end timeout
	tell me to activate -- Être sur que la fenêtre de dialogue soit en premier plan
	display dialog "Géricô - Terminé" buttons {"Ok"} default button "Ok" with title "ICÔNES" giving up after 5 -- Alerte de fin de travail
end open

-- ########################## \\\ FIN DU CODE /// ########################## --

J'accepte même les insultes, donc une réponse de ta part sur ce code seras la bienvenue (cela permet de corriger les erreurs, vue que j'utilise pas le même système).

PS: J'ai l'impression que le modérateur auquel j'ai demandé d'écrire sur ce post Résolu va me bannir (je lui présente des excuses, car je ne pensais pas que cette question allait si loin).

J'espère (faut pas réver) que dans ça grande bonté, il feras une exception pour ma pardonner.

@+

gmaa · 25 Avril 2011

Bonjour,

Ce code fonctionne à merveille sous 10.6.7

Maintenant

on peut "convenir" que ce post est résolu.

Si l'on doit blâmer quelqu'un, ce serait moi qui ai osé suggérer que la réponse initiale pouvait être perfectible...

Et j'ai eu raison!

On ne peut blâmer quelqu'un pour autant de sollicitude (et de compétence).

D'autant que, j'en suis sûr, il y aura d'autres utilisateurs ravis de l'aubaine.

Merci donc encore.

Un utilisateur comblé...

ceslinstinct · 25 Avril 2011

gmaa a dit:
Bonjour,

Ce code fonctionne à merveille sous 10.6.7

Maintenant on peut "convenir" que ce post est résolu.

Si l'on doit blâmer quelqu'un, ce serait moi qui ai osé suggérer que la réponse initiale pouvait être perfectible...

Et j'ai eu raison!

On ne peut blâmer quelqu'un pour autant de sollicitude (et de compétence).

D'autant que, j'en suis sûr, il y aura d'autres utilisateurs ravis de l'aubaine.

Merci donc encore.

Un utilisateur comblé...

Bonjour

Un coup de boule de ta part, me ferais un souvenir de t'avoir aidé dans ta recherche.

PS: Il ne reste qu'a ajouter la barre de défilement pour surveiller le travail du code (et oui ça existe en simple AppleScript) , mais avec SL ça marche pas (du moins je le pense).

@+

gmaa · 25 Avril 2011

Bonjour,

Je me suis fait un jeu d'essai pour tester toutes les configurations.

- En mode application lancée "manuellement" tous les cas fonctionnent.

- En mode glisser-déposer un cas ne fonctionne pas :
glisser-déposer un fichier.

Vraiment un détail...

Message erreur joint.

Je devais tester...

Un coup de boule de ta part, me ferais un souvenir de t'avoir aidé dans ta recherche.

Je l'ai déjà fait. Cela valait bien ça!

ceslinstinct · 27 Avril 2011

gmaa a dit:
Bonjour,

Je me suis fait un jeu d'essai pour tester toutes les configurations.

- En mode application lancée "manuellement" tous les cas fonctionnent.

- En mode glisser-déposer un cas ne fonctionne pas :
glisser-déposer un fichier.

Vraiment un détail... Message erreur joint.

Je devais tester...

Je l'ai déjà fait. Cela valait bien ça!

Bonsoir

Une version modifiée.

Ce quelle fait:

En sélection:

Affichage de la fenêtre de dialogue pour faire le choix entre une image, le contenu des images du dossier sélectionné où les images du dossier sélectionnés ainsi que ces sous-dossiers.

En Glisser-Déposer:

Une image, créer l'icône de cette dernière.

Un dossier ne possédant pas de sous-dossiers, créer les icônes des images de ce dossier.

Un dossier possédant un où plusieurs sous-dossiers, ouvre une fenêtre de dialogue pour savoir si il faut prendre en compte que les images du dossier sélectionné où y compris les images des sous-dossiers.

Si tu désire tester, je te l'envoie par MP car je ne vais pas faire tous les contrôles suivant toutes les extensions qui existent.

A toi de voir si ça correspond à ta recherche.

@+

Affichage des icônes des fichiers sur le bureau

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Membre expert

Sujets similaires