Applescript Infos d'un fichier du finder

[CathyGYM]

Bonsoir à tous,
Quelqu'un saurait-il si l'on peut récupérer avec Applescript les informations concernant un fichier du finder, et en particulier les infos qui s'affichent lorsque l'on fait "Fichier", "Lire les informations" dans le finder.
En fait je cherche à connaitre le nombre de pages d'un document pdf sans l'ouvrir, or la fenêtre "infos" du finder fournit cette donnée, mais y a-t-il une commande AS pour la récupérer ???:eek:

 

[Anonyme]

Bonjour,

Ce sont les métadata de Spotlight qui sont affichés dans "Lire les informations".
On le récupère avec la commande shell mdls

Si le fichier n'est pas indexé, on peut le récupérer par un script python (dans un shell) avec le framework CoreGraphics .

Voici un exemple de script AppleScript

set fichier_pdf to choose file with prompt "Sélectionnez un PDF"
set nombre_de_pages to my getNumberOfPages(fichier_pdf)


on getNumberOfPages(F)
	set F to quoted form of POSIX path of (F as string)
	try -- récupere le metadata kMDItemNumberOfPages de Spotlight
		return last word of (do shell script "/usr/bin/mdls -name kMDItemNumberOfPages " & F) as integer
	on error -- si pas indexé par Spotlight
		return (do shell script "export VERSIONER_PYTHON_PREFER_32_BIT=yes  
/usr/bin/python -c 'import sys, CoreGraphics
try:
   this_pdf = CoreGraphics.CGPDFDocumentCreateWithProvider(CoreGraphics.CGDataProviderCreateWithFilename(sys.argv[1]))
   print this_pdf.getNumberOfPages()
except:
   print 0' " & F) as integer
	end try
end getNumberOfPages

 

[CathyGYM]

Je suis absolument bluffée...
Honnêtement, en postant cette question, je me disais "tu vas coller Mac_Jac"... Eh bien non !
J'avoue que je n'ai pas tout compris de la procédure, mais çà marche parfaitement...
J'espère un jour avoir 1% de tes connaissances en Applescript... et qui sait peut-être 2%

En tout cas, un grand merci... :zen::zen::zen: