-- Endroit où se trouvent les images
set myPath to "WD1800BB:Catalogue:Images:1:14:146:"
-- Dimensions de la page
set LargeurPage to 210
set HauteurPage to 297
set MargeHaute to 10
set MargeBasse to 10
set MargeGauche to 10
set MargeDroite to 10
-- Paramètres divers
set maLargeurFilet to 0.5
-- Nombre d'images par page
set nombreImageLargeur to 3
set nombreImageHauteur to 4
set LargeurColonne to 2
set HauteurTexte to 4
set HauteurColonne to 2
-- Calculs intermédiaires
set LargeurEffective to LargeurPage - MargeGauche - MargeDroite
set HauteurEffective to HauteurPage - MargeHaute - MargeBasse
set nombreColonneLargeur to nombreImageLargeur - 1
set nombreColonneHauteur to nombreImageHauteur - 1
set LargeurImage to (LargeurEffective - (nombreColonneLargeur * LargeurColonne)) / nombreImageLargeur
set HauteurImage to ¬
(HauteurEffective - (nombreColonneHauteur * HauteurColonne) - (HauteurTexte * nombreImageHauteur)) / nombreImageHauteur
set nombreImageParPage to nombreImageLargeur * nombreImageHauteur
tell application "Finder"
try
-- Récupérer que les tiff et les eps (on peut mettre gif, jpeg ou pdf ou autre)
set myFiles to files in folder myPath whose (file type = "TIFF" or file type = "EPSF")
on error
display dialog "Le dossier n'existe pas."
end try
end tell
tell application "InDesign 2.0.2"
set myMarginPreferences to margin preferences
tell myMarginPreferences
set margin top to MargeHaute
set margin bottom to MargeBasse
set margin left to MargeGauche
set margin right to MargeDroite
end tell
set myDocument to make document
tell myDocument
set myDocumentPreferences to document preferences
tell myDocumentPreferences
set page width to LargeurPage
set page height to HauteurPage
end tell
set myTextFramePreferences to text frame preferences
set vertical justification of myTextFramePreferences to center
set zero point to {MargeGauche, MargeHaute}
set myYOffset to 0
set myXOffset to 0
set myYcounter to 0
set myXCounter to 0
set myPage to 1
repeat with myCount from 1 to count of myFiles
set myFile to item myCount of myFiles as string
set myNameFile to name of item myCount of myFiles
if myXCounter ? nombreImageLargeur then
set myXCounter to 0
set myYcounter to myYcounter + 1
set myXOffset to 0
set myYOffset to (HauteurImage + HauteurTexte + HauteurColonne) * myYcounter
end if
if myYcounter ? nombreImageHauteur then
set myXCounter to 0
set myYcounter to 0
set myYOffset to 0
make page
end if
set myXOffset to (LargeurImage + LargeurColonne) * myXCounter
tell page (count of pages)
set myRectangle to make rectangle with properties ¬
{geometric bounds:{myYOffset + 1, myXOffset + 1, myYOffset + HauteurImage - 1, myXOffset + LargeurImage - 1}}
end tell
tell myRectangle
set myImage to place myFile
end tell
set stroke color of myRectangle to swatch "Black"
set stroke weight of myRectangle to maLargeurFilet
set y1 to item 1 of geometric bounds of myImage
set x1 to item 2 of geometric bounds of myImage
set y2 to item 3 of geometric bounds of myImage
set x2 to item 4 of geometric bounds of myImage
set myImageWidth to (x2 - x1)
set myImageHeight to (y2 - y1)
if myImageWidth > LargeurImage or myImageHeight > HauteurImage then
fit myRectangle given proportionally
end if
fit myRectangle given center content
set geometric bounds of myRectangle to {myYOffset, myXOffset, myYOffset + HauteurImage, myXOffset + LargeurImage}
tell page (count of pages)
set myTextFrame to make text frame with properties ¬
{geometric bounds:{myYOffset + HauteurImage, myXOffset, myYOffset + HauteurImage + HauteurTexte, ¬
myXOffset + LargeurImage}, contents:myNameFile}
end tell
set myXCounter to myXCounter + 1
end repeat
end tell
end tell
