Un Applescript (ou autre) pour activer la répétition dans iTunes ?

[Dark Templar]

Salut à tous,
J'aimerais que quand j'appuie sur une touche définie du clavier, cela ait le même effet que si j'appuyait sur le bouton répéter dans iTunes.
Je me suis donc dit que le mieux était que l'appui sur cette touche lance une petite application AppleScript qui ordonne à iTunes de répéter ou non.
Ca marche bien pour play/pause, mais pour répéter je ne connais pas l'ordre à envoyer à iTunes .
Si quelqu'un pouvait m'aider ou me donner une meilleure solution ce serait sympa
Merci d'avance,
Dark :zen:

 

[molgow]

As-tu déjà essayé X-Tunes ? Il ne permet pas réellement de répéter un titre, mais il permet de contrôler la lecture d'iTunes...

 

[Dark Templar]

Salut Laurent,
Malheureusement X-Tunes ne permet pas de répéter le morceau et en plus il faut utiliser la souris après l'avoir appelé.
Ce que j'aimerais c'est ce que Synergy permet : contrôler iTunes depuis le clavier. Pour le moment je peux faire Stop, Play/pause, précédent, suivant et j'aimerais aussi pouvoir faire "répéter" (et augmenter/diminuer le classement du morceau, ce serait royal). J'aimerais bien trouver un autre moyen que synergy car celui-ci est payant et je n'en ai besoin que pour cette fonction.

 

[molgow]

Juste pour info, tu peux contrôler iTunes uniquement avec le clavier en utilisant X-Tunes.
Maintenant, il est vrai qu'il ne fait pas répéter... (mais on peut toujours faire "revenir à la chanson précédente" lorsque le titre est fini)

 

[zeRafioScripter]

Bonjour,

Ca marche bien pour play/pause, mais pour répéter je ne connais pas l'ordre à envoyer à iTunes

tell application "iTunes"
	try
		if song repeat of current playlist is off then
			set song repeat of current playlist to one
		else
			set song repeat of current playlist to off
		end if
	on error errText number errNum
		if errNum = -1728 then
			display dialog "Il n'y a pas de liste de lecture en cours dans iTunes." buttons "OK" default button 1 with icon 1 -- giving up after 10
		else
			display dialog errText buttons "OK" default button 1 with icon 1 -- giving up after 10
		end if
	end try
end tell

et augmenter/diminuer le classement du morceau, ce serait royal

property listRate : {"Aucun", "*", "**", "***", "****", "*****"}

tell application "iTunes"
	activate
	try
		current track
		set userRep to (choose from list listRate without multiple selections allowed)
		set userRep to userRep as text
		if userRep = "Aucun" then
			set myRate to 0
		else
			set myRate to (count userRep) * 20
		end if
		set rating of current track to myRate
	on error errText number errNum
		if errNum = -1731 then
			display dialog "Aucune plage en cours dans iTunes. " buttons "OK" default button 1 with icon 2 -- giving up after 10
		else
			display dialog errText & return & errNum buttons "OK" default button 1 with icon 2 -- giving up after 10
		end if
	end try
end tell

Voilà. Ces 2 scripts devraient répondre à tes désirs.
Pour ce qui est d'y joindre un raccourcis clavier, tu dois savoir comment faire.

 

[Dark Templar]

:affraid:
Respect, merci :zen: