Convertir plusieurs .xls en .pdf

[JacqR]

Bonjour,

Voici un script qui fonctionne avec Microsoft Excel 2016 (version 15.22).

set ces_fichiers to (choose file with multiple selections allowed without invisibles)
tell application "Microsoft Excel" --  fonctionne sous Excel 2016 (version 15.22)
    launch
    repeat with un_fichier in ces_fichiers
        set F to un_fichier as string
        if F ends with ".xls" or F ends with ".xlsx" then --traite seulement les fichiers avec les extensions " .xls(x)"
            if F ends with ".xls" then
                set fichier_PDF to (text 1 thru -4 of F) & "pdf" -- chemin du pdf
            else
                set fichier_PDF to (text 1 thru -5 of F) & "pdf" -- chemin du pdf
            end if
            alias fichier_PDF -- nécessaire sur Microsoft Office 2016 pour ne pas avoir d'erreur avec la commande 'save' (quand c'est un nouveau fichier)
            set wbk1 to open workbook workbook file name F
            save workbook as wbk1 filename fichier_PDF file format PDF file format with overwrite
            close wbk1 saving no
        end if
    end repeat
end tell

​

Si c'est pour Microsoft Excel 2011, utilise ce script

set ces_fichiers to (choose file with multiple selections allowed without invisibles)
tell application "Microsoft Excel" --  fonctionne sous Excel  2011
    launch
    repeat with un_fichier in ces_fichiers
        set F to un_fichier as string
        if F ends with ".xls" or F ends with ".xlsx" then --traite seulement les fichiers avec les extensions " .xls(x)"
            if F ends with ".xls" then
                set fichier_PDF to (text 1 thru -4 of F) & "pdf" -- chemin du pdf
            else
                set fichier_PDF to (text 1 thru -5 of F) & "pdf" -- chemin du pdf
            end if
            open un_fichier
            save workbook as (active workbook) filename fichier_PDF file format PDF file format with overwrite
            close active workbook without saving
        end if
    end repeat
end tell

 

[mikafletcher]

Bonjour, pouvez-vous me dire comment mettre ce script en place ?