Remplacement du disque dur de mon Powerbook?

[OnyX]

Ce que je voudrais savoir c'est si il est possible de prévenir ce genre de mauvaise aventure ?

Oui... Avec un petit script lancé au démarrage de la machine (Via Préférences Système > Comptes > Ouverture), par exemple.. Un script du genre :

set title_ok to "État S.M.A.R.T. vérifié."
set title_nok to "État S.M.A.R.T. non vérifié."
set title_nosupport to "État S.M.A.R.T. non géré."
set msg_ok to "Le disque dur semble fonctionner correctement."
set msg_nok to "Erreur détectée durant la vérification de l'état S.M.A.R.T. du disque. Problème potentiel ou panne imminente ! Sauvegardez au plus vite le contenu du disque dur."
set msg_nosupport to "L'état S.M.A.R.T. n'est pas géré par ce disque."

do shell script "diskutil info / | awk '/SMART Status/ {print $3,$4}'"

if the result is "Verified " then
	display alert title_ok message msg_ok
else if the result is "Not Supported" then
	display alert title_nosupport message msg_nosupport
else if the result is "Not Verified" then
	display alert title_nok message msg_nok
end if

 

[Pierre-Nico]

Super merci !
Une fermeture de session + reouverture suffit ? Ou un redémarrage complet s'impose ?

Merci

 

[OnyX]

Super merci !
Une fermeture de session + reouverture suffit ? Ou un redémarrage complet s'impose ?

Merci

Le script s'exécutera à chaque réouverture de session et à chaque redémarrage.

 

[Pierre-Nico]

Super, existe-t'il d'autre petit script tel que celui-ci, bien pratique ?

 

[OnyX]

Plein... en cherchant bien sur le net ou alors, s'initier à AppleScript. Ce n'est pas très compliqué et ça peut rendre de fiers services.

Allez, un autre petit script qui permet de vérifier la structure du système de fichiers du volume de démarrage :

set titleok to "Vérification terminée."
set titlenotok to "Réparation nécessaire."
set msgok to "Le volume de démarrage semble être en bon état."
set msgnotok to "Démarrer depuis le disque d'installation puis réparer le disque."

try
	do shell script "diskutil verifyVolume /" with administrator privileges
	if the result contains "appears to be OK" then
		display alert titleok message msgok
	else
		display alert titlenotok message msgnotok
	end if
end try

... un autre ?? Allez... c'est encore Noël !

Un script qui permet de choisir le ou les applications à quitter :

tell application "Finder"
	if the (count of processes) is not 0 then
		set visible of every process to true
	end if
	
	set the the_apps to the name of every process whose visible is true
	activate me
	set my_apps to {}
	set the my_apps to choose from list the_apps with prompt ¬
		"Choisissez les applications à quitter. Appuyer sur Commande ou Majuscule pour en sélectionner plusieurs :" cancel button name "Annuler" OK button name "OK" with multiple selections allowed
end tell

repeat with anApp in my_apps
	set anApp to quoted form of anApp
	ignoring application responses
		try
			do shell script "killall -c " & anApp
		end try
	end ignoring
end repeat

 

[Pierre-Nico]

Super, merci beaucoup

Une dernière question, existe-til une site avec une liste de tout les scripts de ce genre ???:siffle:

 

[OnyX]

Il y en a pas mal sur : http://www.macscripter.net/

...mais c'est en anglais. :mouais: